midrange.com code scratchpad
Name:
Command RTVJRNA with API QjoRetrieveJournalInformation
Scriptlanguage:
Plain Text
Tabwidth:
4
Date:
03/28/2008 01:10:00 pm
IP:
Logged
Description:
Command RTVJRNA with API QjoRetrieveJournalInformation
Code:
  1. <b>
  2. File   : QCLSRC
  3. Member : RTVJRNA
  4. Type   : CLLE
  5. Usage  : CRTBNDCL PGM(RTVJRNA)
  6.  
  7. </b>
  8. /*  ===============================================================  */
  9. /*  = Command RtvJrnA    CPP                                      =  */
  10. /*  =   RtvJrnA    CLLE                                           =  */
  11. /*  ===============================================================  */
  12. /*  = Date  : 2008/03/14                                          =  */
  13. /*  = Author: Vengoal Chang                                       =  */
  14. /*  ===============================================================  */
  15.  
  16. PGM PARM(&QUALJRN &RTNLIB &ASP &MSGQ &MSGQLIB &MNGRCV &DLTRCV +
  17.          &MNGRCVDLY &DLTRCVDLY &JRNTYP &JRNSTS &JRNDLVMODE +
  18.          &RCVSIZMFIX                      +
  19.          &RCVSIZRMVI                      +
  20.          &RCVSIZOPT1                      +
  21.          &RCVSIZOPT2                      +
  22.          &RCVSIZOPT3                      +
  23.          &NBRRCV                          +
  24.          &ATCJRNRCV                       +
  25.          &ATCJRNRCVL                      +
  26.          &JRNCACHE                        +
  27.          &RMTJRNTYP                       +
  28.          &JRNOBJ                          +
  29.          &JRNOBJLMT                       +
  30.          &MINJRNENTD                      +
  31.          &MINJRNENTF                      +
  32.          &JRNRCVCNT                       +
  33.          &TEXT                            )
  34.  
  35.      DCL VAR(&QUALJRN) TYPE(*CHAR) LEN(20)
  36.      DCL VAR(&JRNNAME) TYPE(*CHAR) LEN(10)
  37.      DCL VAR(&JRNLIB) TYPE(*CHAR) LEN(10)
  38.      DCL VAR(&RTNLIB) TYPE(*CHAR) LEN(10)      /* STR  LEN*/
  39.      DCL VAR(&ASP   ) TYPE(*DEC ) LEN(3 0)     /*  33    4*/
  40.      DCL VAR(&MSGQ  ) TYPE(*CHAR) LEN(10)      /*  37   10*/
  41.      DCL VAR(&MSGQLIB) TYPE(*CHAR) LEN(10)     /*  47   10*/
  42.      DCL VAR(&MNGRCV ) TYPE(*CHAR) LEN(10)     /*  57    1*/
  43.      DCL VAR(&DLTRCV ) TYPE(*CHAR) LEN( 4)     /*  58    1*/
  44.      DCL VAR(&MNGRCVDLY) TYPE(*DEC) LEN(7 0)   /* 257    4*/
  45.      DCL VAR(&DLTRCVDLY) TYPE(*DEC) LEN(7 0)   /* 261    4*/
  46.      DCL VAR(&JRNTYP   ) TYPE(*CHAR) LEN(10)   /*  66    1*/
  47.      DCL VAR(&JRNSTS   ) TYPE(*CHAR) LEN(10)   /*  68    1*/
  48.      DCL VAR(&JRNDLVMODE) TYPE(*CHAR) LEN(10)  /*  69    1*/
  49.      DCL VAR(&RCVSIZMFIX) TYPE(*CHAR) LEN( 4)  /*  60    1*/
  50.      DCL VAR(&RCVSIZRMVI) TYPE(*CHAR) LEN( 4)  /*  59    1*/
  51.      DCL VAR(&RCVSIZOPT1) TYPE(*CHAR) LEN( 4)  /*  61    1*/
  52.      DCL VAR(&RCVSIZOPT2) TYPE(*CHAR) LEN( 4)  /*  62    1*/
  53.      DCL VAR(&RCVSIZOPT3) TYPE(*CHAR) LEN( 4)  /*  63    1*/
  54.      DCL VAR(&NBRRCV    ) TYPE(*DEC ) LEN(5 0) /* 197    4*/
  55.      DCL VAR(&ATCJRNRCV ) TYPE(*CHAR) LEN(10)  /* 201   10*/
  56.      DCL VAR(&ATCJRNRCVL) TYPE(*CHAR) LEN(10)  /* 211   10*/
  57.      DCL VAR(&JRNCACHE  ) TYPE(*CHAR) LEN( 4)  /* 196    1*/
  58.      DCL VAR(&RMTJRNTYP ) TYPE(*CHAR) LEN(10)  /*  67    1*/
  59.      DCL VAR(&JRNOBJ    ) TYPE(*DEC ) LEN(15 0)/* 309    4*/
  60.      DCL VAR(&JRNOBJLMT ) TYPE(*CHAR) LEN(1)   /* 308    1*/
  61.      DCL VAR(&MINJRNENTD) TYPE(*CHAR) LEN(1)   /* 186    1*/
  62.      DCL VAR(&MINJRNENTF) TYPE(*CHAR) LEN(1)   /* 187    1*/
  63.      DCL VAR(&JRNRCVCNT ) TYPE(*DEC ) LEN(11 0)/* 341    4*/
  64.      DCL VAR(&TEXT      ) TYPE(*CHAR) LEN(50)  /* 136   50*/
  65.  
  66.      DCL        VAR(&WORK) TYPE(*CHAR) LEN(4)
  67.      DCL VAR(&RCVRNAME) TYPE(*CHAR) LEN(10)
  68.      DCL VAR(&RCVRLIB) TYPE(*CHAR) LEN(10)
  69.  
  70.      DCL VAR(&RCV) TYPE(*CHAR) LEN(512)
  71.      DCL VAR(&RCVLEN) TYPE(*CHAR) LEN(4)
  72.      DCL VAR(&JRNRCV) TYPE(*CHAR) LEN(20)
  73.      DCL VAR(&SEQNBR) TYPE(*CHAR) LEN(20)
  74.      DCL VAR(&RCVRINFO) TYPE(*CHAR) LEN(20)
  75.  
  76.      DCL        VAR(&MSGID) TYPE(*CHAR) LEN(7)
  77.      DCL        VAR(&MSGDTA) TYPE(*CHAR) LEN(256)
  78.      DCL        VAR(&MSGF) TYPE(*CHAR) LEN(10)
  79.      DCL        VAR(&MSGFLIB) TYPE(*CHAR) LEN(10)
  80.      DCL        VAR(&MSGTXT) TYPE(*CHAR) LEN(256)
  81.  
  82.      MONMSG     MSGID(CPF0000 MCH0000) EXEC(GOTO CMDLBL(ERROR))
  83.  
  84.      CHGVAR     VAR(&JRNNAME) VALUE(%SST(&QUALJRN  1 10))
  85.      CHGVAR     VAR(&JRNLIB) VALUE(%SST(&QUALJRN 11 10))
  86.      CHKOBJ     OBJ(&JRNLIB/&JRNNAME) OBJTYPE(*JRN)
  87.  
  88.      IF (&JRNLIB *EQ '*LIBL') Do
  89.              RTVOBJD    OBJ(&JRNLIB/&JRNNAME) OBJTYPE(*JRN) +
  90.                           RTNLIB(&RTNLIB)
  91.              MONMSG     MCH3601
  92.      EndDo
  93.      Else Do
  94.              CHGVAR     VAR(&RTNLIB) VALUE(&JRNLIB)
  95.              MONMSG     MCH3601
  96.      EndDo
  97.  
  98.      CHGVAR   VAR( %bin(&RCVLEN ))  VALUE(512)
  99.      CHGVAR   %SST(&RCVRINFO 1 10) &JRNNAME
  100.      CHGVAR   %SST(&RCVRINFO 11 10) &JRNLIB
  101.  
  102.      CALLPRC PRC('QjoRetrieveJournalInformation') +
  103.           PARM((&RCV) (&RCVLEN) (&RCVRINFO) +
  104.           ('RJRN0100') (X'00000000') +
  105.           (*OMIT))
  106. /* ASP */
  107.      CHGVAR VAR(&JRNRCV) VALUE(%SST(&RCV 201 20))
  108.      CHGVAR     VAR(&WORK) VALUE(%SST(&RCV 33 4))
  109.      CHGVAR     VAR(&ASP) VALUE(%BIN(&WORK))
  110.      MONMSG     MCH3601
  111.  
  112.      CHGVAR VAR(&MSGQ    ) VALUE(%SST(&RCV 37  10))
  113.      MONMSG     MCH3601
  114.      CHGVAR VAR(&MSGQLIB) VALUE(%SST(&RCV  47 10))
  115.      MONMSG     MCH3601
  116.      CHGVAR VAR(&ATCJRNRCV)  VALUE(%SST(&RCV 201 10))
  117.      MONMSG     MCH3601
  118.      CHGVAR VAR(&ATCJRNRCVL) VALUE(%SST(&RCV 211 10))
  119.      MONMSG     MCH3601
  120.      CHGVAR VAR(&ATCJRNRCVL) VALUE(%SST(&RCV 211 10))
  121.      MONMSG     MCH3601
  122.      CHGVAR VAR(&JRNOBJLMT ) VALUE(%SST(&RCV 308  1))
  123.      MONMSG     MCH3601
  124.      CHGVAR VAR(&MINJRNENTD) VALUE(%SST(&RCV 186  1))
  125.      MONMSG     MCH3601
  126.      CHGVAR VAR(&MINJRNENTF) VALUE(%SST(&RCV 187  1))
  127.      MONMSG     MCH3601
  128.  
  129. /* MNGRCV ' '   remote journal */
  130. /*        '0'   user manage    */
  131. /*        '1'   system manage  */
  132.      If (%SST(&RCV 57  1 ) *EQ '1')  Do
  133.        CHGVAR VAR(&MNGRCV  ) VALUE('*SYSTEM')
  134.        MONMSG     MCH3601
  135.      EndDo
  136.      If (%SST(&RCV 57  1 ) *EQ '0')  Do
  137.        CHGVAR VAR(&MNGRCV  ) VALUE('*USER')
  138.        MONMSG     MCH3601
  139.      EndDo
  140.      If (%SST(&RCV 57  1 ) *EQ ' ')  Do
  141.        CHGVAR VAR(&MNGRCV  ) VALUE(' ')
  142.        MONMSG     MCH3601
  143.      EndDo
  144.  
  145.      If (%SST(&RCV 58  1 ) *EQ '1')  Do
  146.        CHGVAR VAR(&DLTRCV ) VALUE('*YES')
  147.        MONMSG     MCH3601
  148.      EndDo
  149.      Else Do
  150.        CHGVAR VAR(&DLTRCV ) VALUE('*NO')
  151.        MONMSG     MCH3601
  152.      EndDo
  153.  
  154.      CHGVAR     VAR(&WORK) VALUE(%SST(&RCV 257 4))
  155.      CHGVAR     VAR(&MNGRCVDLY) VALUE(%BIN(&WORK))
  156.      MONMSG     MCH3601
  157.  
  158.      CHGVAR     VAR(&WORK) VALUE(%SST(&RCV 261 4))
  159.      CHGVAR     VAR(&DLTRCVDLY) VALUE(%BIN(&WORK))
  160.      MONMSG     MCH3601
  161.  
  162. /* Journal type          */
  163.      If (%SST(&RCV 66  1 ) *EQ '1')  Do
  164.        CHGVAR VAR(&JRNTYP ) VALUE('*REMOTE')
  165.        MONMSG     MCH3601
  166.      EndDo
  167.      Else Do
  168.        CHGVAR VAR(&JRNTYP ) VALUE('*LOCAL')
  169.        MONMSG     MCH3601
  170.      EndDo
  171.  
  172. /* Journal state         */
  173.      If (%SST(&RCV 68  1 ) *EQ '0')  Do
  174.        CHGVAR VAR(&JRNSTS ) VALUE('*INACTIVE')
  175.        MONMSG     MCH3601
  176.      EndDo
  177.      If (%SST(&RCV 68  1 ) *EQ '1')  Do
  178.        CHGVAR VAR(&JRNSTS ) VALUE('*ACTIVE')
  179.        MONMSG     MCH3601
  180.      EndDo
  181.      If (%SST(&RCV 68  1 ) *EQ '2')  Do
  182.        CHGVAR VAR(&JRNSTS ) VALUE('*FAILED')
  183.        MONMSG     MCH3601
  184.      EndDo
  185.      If (%SST(&RCV 68  1 ) *EQ '4')  Do
  186.        CHGVAR VAR(&JRNSTS ) VALUE('*INACTPEND')
  187.        MONMSG     MCH3601
  188.      EndDo
  189.      If (%SST(&RCV 68  1 ) *EQ '5')  Do
  190.        CHGVAR VAR(&JRNSTS ) VALUE('*STANDBY')
  191.        MONMSG     MCH3601
  192.      EndDo
  193.  
  194. /* Journal delivery mode */
  195.      If (%SST(&RCV 69  1 ) *EQ '0')  Do
  196.        CHGVAR VAR(&JRNDLVMODE) VALUE('*NA'   )
  197.        MONMSG     MCH3601
  198.      EndDo
  199.      If (%SST(&RCV 69  1 ) *EQ '1')  Do
  200.        CHGVAR VAR(&JRNDLVMODE) VALUE('*ASYNC')
  201.        MONMSG     MCH3601
  202.      EndDo
  203.      If (%SST(&RCV 69  1 ) *EQ '2')  Do
  204.        CHGVAR VAR(&JRNDLVMODE) VALUE('*SYNC')
  205.        MONMSG     MCH3601
  206.      EndDo
  207.      If (%SST(&RCV 69  1 ) *EQ '3')  Do
  208.        CHGVAR VAR(&JRNDLVMODE) VALUE('*ASYNCPEND')
  209.        MONMSG     MCH3601
  210.      EndDo
  211.      If (%SST(&RCV 69  1 ) *EQ '4')  Do
  212.        CHGVAR VAR(&JRNDLVMODE) VALUE('*SYNCPEND')
  213.        MONMSG     MCH3601
  214.      EndDo
  215.  
  216. /* Receiver size option *RMVINTENT */
  217.      If (%SST(&RCV 59  1 ) *EQ '1')  Do
  218.        CHGVAR VAR(&RCVSIZRMVI ) VALUE('*YES')
  219.        MONMSG     MCH3601
  220.      EndDo
  221.      Else Do
  222.        CHGVAR VAR(&RCVSIZRMVI ) VALUE('*NO')
  223.        MONMSG     MCH3601
  224.      EndDo
  225.  
  226. /* Receiver size option *MINFIXLEN */
  227.      If (%SST(&RCV 60  1 ) *EQ '1')  Do
  228.        CHGVAR VAR(&RCVSIZMFIX ) VALUE('*YES')
  229.        MONMSG     MCH3601
  230.      EndDo
  231.      Else Do
  232.        CHGVAR VAR(&RCVSIZMFIX ) VALUE('*NO')
  233.        MONMSG     MCH3601
  234.      EndDo
  235. /* Receiver size option *MAXOPT1   */
  236.      If (%SST(&RCV 61  1 ) *EQ '1')  Do
  237.        CHGVAR VAR(&RCVSIZOPT1 ) VALUE('*YES')
  238.        MONMSG     MCH3601
  239.      EndDo
  240.      Else Do
  241.        CHGVAR VAR(&RCVSIZOPT1 ) VALUE('*NO')
  242.        MONMSG     MCH3601
  243.      EndDo
  244. /* Receiver size option *MAXOPT2   */
  245.      If (%SST(&RCV 62  1 ) *EQ '1')  Do
  246.        CHGVAR VAR(&RCVSIZOPT2 ) VALUE('*YES')
  247.        MONMSG     MCH3601
  248.      EndDo
  249.      Else Do
  250.        CHGVAR VAR(&RCVSIZOPT2 ) VALUE('*NO')
  251.        MONMSG     MCH3601
  252.      EndDo
  253. /* Receiver size option *MAXOPT3   */
  254.      If (%SST(&RCV 63  1 ) *EQ '1')  Do
  255.        CHGVAR VAR(&RCVSIZOPT3 ) VALUE('*YES')
  256.        MONMSG     MCH3601
  257.      EndDo
  258.      Else Do
  259.        CHGVAR VAR(&RCVSIZOPT3 ) VALUE('*NO')
  260.        MONMSG     MCH3601
  261.      EndDo
  262.  
  263. /* Number of receiver  */
  264.      CHGVAR     VAR(&WORK) VALUE(%SST(&RCV 197 4))
  265.      CHGVAR     VAR(&NBRRCV   ) VALUE(%BIN(&WORK))
  266.      MONMSG     MCH3601
  267.  
  268. /* Journal cache       */
  269. /*        ' '   remote journal */
  270. /*        '0'   no cache       */
  271. /*        '1'   cache          */
  272.      If (%SST(&RCV 196 1 ) *EQ ' ')  Do
  273.        CHGVAR VAR(&JRNCACHE) VALUE('*NA' )
  274.        MONMSG     MCH3601
  275.      EndDo
  276.      If (%SST(&RCV 196 1 ) *EQ '1')  Do
  277.        CHGVAR VAR(&JRNCACHE) VALUE('*YES')
  278.        MONMSG     MCH3601
  279.      EndDo
  280.      If (%SST(&RCV 196 1 ) *EQ '0')  Do
  281.        CHGVAR VAR(&JRNCACHE ) VALUE('*NO')
  282.        MONMSG     MCH3601
  283.      EndDo
  284.  
  285. /* Remote journal type */
  286.      If (%SST(&RCV 67 1 ) *EQ '0')  Do
  287.        CHGVAR VAR(&RMTJRNTYP) VALUE('*LOCAL')
  288.        MONMSG     MCH3601
  289.      EndDo
  290.      If (%SST(&RCV 67 1 ) *EQ '1')  Do
  291.        CHGVAR VAR(&RMTJRNTYP) VALUE('*TYPE1')
  292.        MONMSG     MCH3601
  293.      EndDo
  294.      If (%SST(&RCV 67 1 ) *EQ '2')  Do
  295.        CHGVAR VAR(&RMTJRNTYP) VALUE('*TYPE2')
  296.        MONMSG     MCH3601
  297.      EndDo
  298.  
  299. /* Number of object journaled */
  300.      CHGVAR     VAR(&WORK) VALUE(%SST(&RCV 309 4))
  301.      CHGVAR     VAR(&JRNOBJ   ) VALUE(%BIN(&WORK))
  302.      MONMSG     MCH3601
  303. /* Journal recovery count from V5R4   */
  304.      CHGVAR     VAR(&WORK) VALUE(%SST(&RCV 341 4))
  305.      CHGVAR     VAR(&JRNRCVCNT) VALUE(%BIN(&WORK))
  306.      MONMSG     MCH3601
  307.  
  308.      Return
  309.  
  310. /*  ===============================================================  */
  311. /*  = Error routine                                               =  */
  312. /*  ===============================================================  */
  313.  
  314. Error:
  315.  
  316.   RcvMsg     MsgType( *Excp )                                         +
  317.              MsgDta( &MsgDta )                                        +
  318.              MsgID( &MsgID )                                          +
  319.              MsgF( &MsgF )                                            +
  320.              MsgFLib( &MsgFLib )
  321.   MonMsg     ( CPF0000 MCH0000 )
  322.  
  323. SndMsg:
  324.  
  325.   SndPgmMsg  MsgID( &MsgID )                                          +
  326.              MsgF( &MsgFLib/&MsgF )                                   +
  327.              MsgDta( &MsgDta )                                        +
  328.              MsgType( *Escape )
  329.   MonMsg     ( CPF0000 MCH0000 )
  330.  
  331. /*  ===============================================================  */
  332. /*  = End of program                                              =  */
  333. /*  ===============================================================  */
  334.  
  335. ENDPGM
  336.  
  337. <b>
  338. File   : QCMDSRC
  339. Member : RTVJRNA
  340. Type   : CMD
  341. Usage  : CRTCMD CMD(your-lib/RTVJRNA) PGM(your-lib/RTVJRNA) ALLOW(*IPGM *BPGM) 
  342. </b>
  343. /*  ===============================================================  */
  344. /*  = Command....... RtvJrnA                                      =  */
  345. /*  = CPP........... RtvJrnA    CLLE                              =  */
  346. /*  = Description... Retrieve journal attributes                  =  */
  347. /*  =                                                             =  */
  348. /*  = CrtCmd      Cmd( RtvJrnA    )                               =  */
  349. /*  =             Pgm( RtvJrnA    )                               =  */
  350. /*  =             Pgm( RtvJrnA    )                               =  */
  351. /*  =             SrcFile( YourSourceFile )                       =  */
  352. /*  =             Allow(*Ipgm *Bpgm)                              =  */
  353. /*  ===============================================================  */
  354. /*  = Date  : 2008/03/14                                          =  */
  355. /*  = Author: Vengoal Chang                                       =  */
  356. /*  ===============================================================  */
  357. /*  = Parameter     Description                                   =  */
  358. /*  =   JRN         The qualified name of the journal to be retrieved*/
  359. /*  =   RTNLIB      The library containing the journal.           =  */
  360. /*  =   ASP         The Auxiliary Storage pool containing the     =  */
  361. /*  =               journal.                                      =  */
  362. /*  =   MSGQ        The Message Queue where messages from the     =  */
  363. /*  =               journal sent.such as if the threshold has     =  */
  364. /*  =               been reached.                                 =  */
  365. /*  =   MSGQLIB     The Message Queue Library where messages from =  */
  366. /*  =               the journal are sent such as if the threshold =  */
  367. /*  =               has been reached.                             =  */
  368. /*  =   MNGRCV      The Manage Receiver option as specified on    =  */
  369. /*  =               CRTJRN. Either *USER or *SYSTEM is returned.  =  */
  370. /*  =   DLTRCV      The Delete Receiver option as specified on    =  */
  371. /*  =               CRTJRN. Either *NO or *YES is returned.       =  */
  372. /*  =   MNGRCVDLY   The time in  minutes to be used to delay the  =  */
  373. /*  =               attempt to delete a journal receiver, if the  =  */
  374. /*  =               system cannot allocate it and  DLTRCV(*YES)   =  */
  375. /*  =               is  specified.                                =  */
  376. /*  =   DLTRCVDLY   The time in  minutes to be used to delay the  =  */
  377. /*  =               next attempt to attach a new journal receiver =  */
  378. /*  =               for system managed receivers.                 =  */
  379. /*  =   JRNTYP      The type of journal.                          =  */
  380. /*  =               *LOCAL or *REMOTE is returned.                =  */
  381. /*  =   JRNSTS      The status of the journal.                    =  */
  382. /*  =               *INACTIVE, *ACTIVE, *FAILED, or *INACTPEND    =  */
  383. /*  =               will be returned.                             =  */
  384. /*  =   JRNDLVMODE  The delivery mode of the journal.             =  */
  385. /*  =               *NA  if it is not applicable, such as local   =  */
  386. /*  =               journal.                                      =  */
  387. /*  =               *ASYNC, *SYNC, *ASYNCPEND, and *SYNCPEND will =  */
  388. /*  =               will be returned for remote journal.          =  */
  389. /*  =   RCVSIZMFIX  The CRTJRN RCVSIZOPT(*MINFIXLEN) option.      =  */
  390. /*  =               Blank is returned for remote journal.         =  */
  391. /*  =               *YES or *NO is returned depending on whether  =  */
  392. /*  =               *MINFIXLEN  was specified.                    =  */
  393. /*  =   RCVSIZRMVI  The CRTJRN RCVSIZOPT(*RMVINTENT) option.      =  */
  394. /*  =               Blank is returned for remote journal.         =  */
  395. /*  =               *YES or *NO is returned depending on whether  =  */
  396. /*  =               *RMVINTENT  was specified.                    =  */
  397. /*  =   RCVSIZOPT1  The CRTJRN RCVSIZOPT(*MAXOPT1)   option.      =  */
  398. /*  =               Blank is returned for remote journal.         =  */
  399. /*  =               *YES or *NO is returned depending on whether  =  */
  400. /*  =               *MAXOPT1    was specified.                    =  */
  401. /*  =   RCVSIZOPT2  The CRTJRN RCVSIZOPT(*MAXOPT2)   option.      =  */
  402. /*  =               Blank is returned for remote journal.         =  */
  403. /*  =               *YES or *NO is returned depending on whether  =  */
  404. /*  =               *MAXOPT2    was specified.                    =  */
  405. /*  =   RCVSIZOPT3  The CRTJRN RCVSIZOPT(*MAXOPT3)   option.      =  */
  406. /*  =               Blank is returned for remote journal.         =  */
  407. /*  =               *YES or *NO is returned depending on whether  =  */
  408. /*  =               *MAXOPT3    was specified.                    =  */
  409. /*  =   NBRRCV      The number of receivers currently attached.   =  */
  410. /*  =   ACTJRNRCV   The name of the current attached journal      =  */
  411. /*  =               receiver.                                     =  */
  412. /*  =   ACTJRNRCVL  The name of the library of the attached       =  */
  413. /*  =               journal receiver.                             =  */
  414. /*  =   JRNCACHE    Whether journal entries will be cached, before=  */
  415. /*  =               being written out to disk.                    =  */
  416. /*  =               *NA for remote journal, *YES, *NO will be     =  */
  417. /*  =               returned.                                     =  */
  418. /*  =   RMTJRNTYP   The type of Remote Journal. *LOCAL, *TYPE1    =  */
  419. /*  =               or *TYPE2 will be returned.                   =  */
  420. /*  =   JRNOBJ      The total number of objects being journaled   =  */
  421. /*  =               to the journal.                               =  */
  422. /*  =   JRNOBJLMT   The maximum number of objects that may be     =  */
  423. /*  =               journaled to the journal.(From V5R4)          =  */
  424. /*  =   MINJRNENTD  Whether journal entries to data areas will be =  */
  425. /*  =               minimized in size.                            =  */
  426. /*  =   MINJRNENTF  Whether journal entries to files will be      =  */
  427. /*  =               minimized in size.                            =  */
  428. /*  =   JRNRCVCNT   Journal recovery count (From V5R4)            =  */
  429. /*  =               Describes whether a faster abnormal IPL will  =  */
  430. /*  =               occur.                                        =  */
  431. /*  =   TEXT        The text description of the Journal.          =  */
  432. /*  =                                                             =  */
  433. /*  ===============================================================  */
  434.              CMD        PROMPT('Retrieve Journal Attributes')
  435.  
  436.              PARM       KWD(JRN) TYPE(QUAL) MIN(1) +
  437.                           PROMPT('Journal')
  438.  
  439.              PARM       KWD(RTNLIB) TYPE(*CHAR) LEN(10) RTNVAL(*YES) +
  440.                           PROMPT('CL var for RTNLIB       (10)')
  441.              PARM       KWD(ASP) TYPE(*DEC) LEN(3 0) RTNVAL(*YES) +
  442.                           PROMPT('CL var for ASP         (3 0)')
  443.              PARM       KWD(MSGQ  ) TYPE(*CHAR) LEN(10) RTNVAL(*YES) +
  444.                           PROMPT('CL var for MSGQ         (10)')
  445.              PARM       KWD(MSGQLIB) TYPE(*CHAR) LEN(10) +
  446.                           RTNVAL(*YES) PROMPT('CL var for +
  447.                           MSGQLIB      (10)')
  448.              PARM       KWD(MNGRCV ) TYPE(*CHAR) LEN(10) +
  449.                           RTNVAL(*YES) PROMPT('CL var for +
  450.                           MNGRCV       (10)')
  451.              PARM       KWD(DLTRCV) TYPE(*CHAR) LEN( 4) RTNVAL(*YES) +
  452.                           PROMPT('CL var for DLTRCV       (10)')
  453.              PARM       KWD(MNGRCVDLY) TYPE(*DEC) LEN( 7 0) +
  454.                           RTNVAL(*YES) PROMPT('CL var for +
  455.                           MNGRCVDLY  (15 0)')
  456.              PARM       KWD(DLTRCVDLY) TYPE(*DEC) LEN( 7 0) +
  457.                           RTNVAL(*YES) PROMPT('CL var for +
  458.                           DLTRCVDLY  (15 0)')
  459.              PARM       KWD(JRNTYP ) TYPE(*CHAR) LEN(10) +
  460.                           RTNVAL(*YES) PROMPT('CL var for +
  461.                           JRNTYP       (10)')
  462.              PARM       KWD(JRNSTS ) TYPE(*CHAR) LEN(10) +
  463.                           RTNVAL(*YES) PROMPT('CL var for +
  464.                           JRNSTS       (10)')
  465.              PARM       KWD(JRNDLVMODE ) TYPE(*CHAR) LEN(10) +
  466.                           RTNVAL(*YES) PROMPT('CL var for +
  467.                           JRNDLVMODE   (10)')
  468.              PARM       KWD(RCVSIZMFIX ) TYPE(*CHAR) LEN( 4) +
  469.                           RTNVAL(*YES) PROMPT('CL var for +
  470.                           RCVSIZMFIX   ( 4)')
  471.              PARM       KWD(RCVSIZRMVI ) TYPE(*CHAR) LEN( 4) +
  472.                           RTNVAL(*YES) PROMPT('CL var for +
  473.                           RCVSIZRMVI   ( 4)')
  474.              PARM       KWD(RCVSIZOPT1 ) TYPE(*CHAR) LEN( 4) +
  475.                           RTNVAL(*YES) PROMPT('CL var for +
  476.                           RCVSIZOPT1   ( 4)')
  477.              PARM       KWD(RCVSIZOPT2 ) TYPE(*CHAR) LEN( 4) +
  478.                           RTNVAL(*YES) PROMPT('CL var for +
  479.                           RCVSIZOPT2   ( 4)')
  480.              PARM       KWD(RCVSIZOPT3 ) TYPE(*CHAR) LEN( 4) +
  481.                           RTNVAL(*YES) PROMPT('CL var for +
  482.                           RCVSIZOPT3   ( 4)')
  483.              PARM       KWD(NBRRCV    ) TYPE(*DEC) LEN( 5 0) +
  484.                           RTNVAL(*YES) PROMPT('CL var for +
  485.                           NBRRCV      (5 0)')
  486.              PARM       KWD(ACTJRNRCV ) TYPE(*CHAR) LEN(10) +
  487.                           RTNVAL(*YES) PROMPT('CL var for +
  488.                           ACTJRNRCV    (10)')
  489.              PARM       KWD(ACTJRNRCVL) TYPE(*CHAR) LEN(10) +
  490.                           RTNVAL(*YES) PROMPT('CL var for +
  491.                           ACTJRNRCVL   (10)')
  492.              PARM       KWD(JRNCACHE  ) TYPE(*CHAR) LEN( 4) +
  493.                           RTNVAL(*YES) PROMPT('CL var for +
  494.                           JRNCACHE     ( 4)')
  495.              PARM       KWD(RMTJRNTYP ) TYPE(*CHAR) LEN(10) +
  496.                           RTNVAL(*YES) PROMPT('CL var for +
  497.                           RMTJRNTYP    (10)')
  498.              PARM       KWD(JRNOBJ   ) TYPE(*DEC) LEN(15 0) +
  499.                           RTNVAL(*YES) PROMPT('CL var for +
  500.                           JRNOBJ     (15 0)')
  501.              PARM       KWD(JRNOBJLMT ) TYPE(*CHAR) LEN( 1) +
  502.                           RTNVAL(*YES) PROMPT('CL var for +
  503.                           JRNOBJLMT    ( 1)')
  504.              PARM       KWD(MINJRNENTD ) TYPE(*CHAR) LEN( 1) +
  505.                           RTNVAL(*YES) PROMPT('CL var for +
  506.                           MINJRNENTD   ( 1)')
  507.              PARM       KWD(MINJRNENTF ) TYPE(*CHAR) LEN( 1) +
  508.                           RTNVAL(*YES) PROMPT('CL var for +
  509.                           MINJRNENTF   ( 1)')
  510.              PARM       KWD(JRNRCVCNT) TYPE(*DEC) LEN(11 0) +
  511.                           RTNVAL(*YES) PROMPT('CL var for +
  512.                           JRNRCVCNT  (11 0)')
  513.              PARM       KWD(TEXT     ) TYPE(*CHAR) LEN(50) +
  514.                           RTNVAL(*YES) PROMPT('CL var for +
  515.                           TEXT         (50)')
  516.  
  517.  
  518.  QUAL:       QUAL       TYPE(*NAME) LEN(10) SPCVAL((*ALL)) EXPR(*YES)
  519.              QUAL       TYPE(*NAME) LEN(10) DFT(*LIBL) +
  520.                           SPCVAL((*LIBL) (*CURLIB)) EXPR(*YES) +
  521.                           PROMPT('Library')
  522.  
© 2004-2019 by midrange.com generated in 0.008s valid xhtml & css