midrange.com code scratchpad
Name:
Command RTVJRNRCVA with API QjoRtvJrnReceiverInformation
Scriptlanguage:
Plain Text
Tabwidth:
4
Date:
03/28/2008 01:20:37 pm
IP:
Logged
Description:
Command RTVJRNRCVA with API QjoRtvJrnReceiverInformation
Code:
  1. <b>
  2. File   : QCLSRC
  3. Member : RTVJRNRCVA
  4. Type   : CLLE
  5. Usage  : CRTBNDCL PGM(RTVJRNRCVA)
  6.  
  7.  
  8. </b>
  9. /*  ===============================================================  */
  10. /*  = Command RtvJrnRcvA CPP                                      =  */
  11. /*  =   RtvJrnRcvA CLLE                                           =  */
  12. /*  ===============================================================  */
  13. /*  = Date  : 2008/03/14                                          =  */
  14. /*  = Author: Vengoal Chang                                       =  */
  15. /*  ===============================================================  */
  16.  
  17. PGM PARM(&QUALRCVR &RTNLIB &STATUS &ASP &THRESHOLD &SIZE &NBRENTP +
  18.          &MAXNULIND &MAXENTLEN &MAXENTLENP &RCVMAXOPT +
  19.          &FSTSEQNBRP &LSTSEQNBRP &ACTDATTIM &DACTDATTIM &SAVDATTIM +
  20.          &JRNNAME &JRNLIB &TEXT)
  21.  
  22.              DCL        VAR(&QUALRCVR) TYPE(*CHAR) LEN(20)
  23.              DCL        VAR(&RCVRNAME) TYPE(*CHAR) LEN(10)
  24.              DCL        VAR(&RCVRLIB) TYPE(*CHAR) LEN(10)
  25.              DCL        VAR(&RTNLIB ) TYPE(*CHAR) LEN(10)
  26.              DCL        VAR(&JRNNAME) TYPE(*CHAR) LEN(10)
  27.              DCL        VAR(&JRNLIB) TYPE(*CHAR) LEN(10)
  28.              DCL        VAR(&THRESHOLD) TYPE(*DEC) LEN( 7 0)
  29.              DCL        VAR(&SIZE)      TYPE(*DEC) LEN( 7 0)
  30.              DCL        VAR(&ASP )      TYPE(*DEC) LEN(3 0)
  31.              DCL        VAR(&NBRENT   ) TYPE(*DEC) LEN(10 0)
  32.              DCL        VAR(&NBRENTP  ) TYPE(*DEC) LEN(15 0)
  33.              DCL        VAR(&NBRENT2  ) TYPE(*CHAR) LEN(20)
  34.              DCL        VAR(&MAXENTLEN) TYPE(*DEC) LEN( 7 0)
  35.              DCL        VAR(&MAXENTLENP) TYPE(*DEC) LEN(15 0)
  36.              DCL        VAR(&MAXENTLEN2) TYPE(*CHAR) LEN(20)
  37.              DCL        VAR(&MAXNULIND) TYPE(*DEC) LEN(15 0)
  38.              DCL        VAR(&MINDTAARA) TYPE(*CHAR) LEN(1)
  39.              DCL        VAR(&MINDTAFLE) TYPE(*CHAR) LEN(1)
  40.              DCL        VAR(&RCVMAXOPT) TYPE(*CHAR) LEN(1)
  41.              DCL        VAR(&FSTSEQNBR) TYPE(*DEC) LEN(15 0)
  42.              DCL        VAR(&LSTSEQNBR) TYPE(*DEC) LEN(15 0)
  43.              DCL        VAR(&FSTSEQNBRP) TYPE(*DEC) LEN(15 0)
  44.              DCL        VAR(&FSTSEQNBRL) TYPE(*CHAR) LEN(20)
  45.              DCL        VAR(&LSTSEQNBRP) TYPE(*DEC) LEN(15 0)
  46.              DCL        VAR(&LSTSEQNBRL) TYPE(*CHAR) LEN(20)
  47.  
  48.              DCL        VAR(&STATUS) TYPE(*CHAR) LEN(1)
  49.          /*   1  *ATTACHED   Currently attached                     */
  50.          /*   2  *ONLINE     On line, detached, but not saved       */
  51.          /*   3  *SAVED      On line, detached, and saved           */
  52.          /*   4  *FREED      On line, detached, saved and stg freed */
  53.          /*   5  *PARTIAL    See note                               */
  54.          /*   6  *EMPTY      Never attached                         */
  55.  
  56.              DCL        VAR(&ACTDATTIM) TYPE(*CHAR) LEN(13)
  57.                         /* CYYMMDDHHMMSS */
  58.              DCL        VAR(&DACTDATTIM) TYPE(*CHAR) LEN(13)
  59.              DCL        VAR(&SAVDATTIM) TYPE(*CHAR) LEN(13)
  60.              DCL        VAR(&TEXT) TYPE(*CHAR) LEN(50)
  61.  
  62.              DCL        VAR(&RCV) TYPE(*CHAR) LEN(512)
  63.              DCL        VAR(&RCVLEN) TYPE(*CHAR) LEN(4)
  64.              DCL        VAR(&JRNRCV) TYPE(*CHAR) LEN(20)
  65.              DCL        VAR(&FSTSEQNBRC) TYPE(*CHAR) LEN(20)
  66.              DCL        VAR(&LSTSEQNBRC) TYPE(*CHAR) LEN(20)
  67.              DCL        VAR(&RCVRINFO) TYPE(*CHAR) LEN(20)
  68.              DCL        VAR(&WORK) TYPE(*CHAR) LEN(4)
  69.  
  70.              DCL        VAR(&MSGID) TYPE(*CHAR) LEN(7)
  71.              DCL        VAR(&MSGDTA) TYPE(*CHAR) LEN(256)
  72.              DCL        VAR(&MSGF) TYPE(*CHAR) LEN(10)
  73.              DCL        VAR(&MSGFLIB) TYPE(*CHAR) LEN(10)
  74.              DCL        VAR(&MSGTXT) TYPE(*CHAR) LEN(256)
  75.  
  76.           MONMSG     MSGID(CPF0000 MCH0000) EXEC(GOTO CMDLBL(ERROR))
  77.  
  78.              CHGVAR     VAR(&RCVRNAME) VALUE(%SST(&QUALRCVR  1 10))
  79.              CHGVAR     VAR(&RCVRLIB ) VALUE(%SST(&QUALRCVR 11 10))
  80.              CHKOBJ     OBJ(&RCVRLIB/&RCVRNAME) OBJTYPE(*JRNRCV)
  81.              If         (&RCVRLIB *EQ '*LIBL') Do
  82.              RTVOBJD    OBJ(&RCVRLIB/&RCVRNAME) OBJTYPE(&JRNRCV) +
  83.                           RTNLIB(&RTNLIB)
  84.              MONMSG     MCH3601
  85.              EndDo
  86.              Else Do
  87.              CHGVAR     VAR(&RTNLIB) VALUE(&RCVRLIB)
  88.              MONMSG     MCH3601
  89.              EndDo
  90.  
  91.              CHGVAR     VAR(%BIN(&RCVLEN)) VALUE(512)
  92.              CHGVAR     VAR(&JRNRCV) VALUE(&RCVRNAME *CAT &RCVRLIB)
  93.              CALLPRC PRC('QjoRtvJrnReceiverInformation') +
  94.                         PARM((&RCV) (&RCVLEN) (&JRNRCV) +
  95.                         ('RRCV0100') (*OMIT))
  96.              CHGVAR     VAR(&JRNNAME) VALUE(%SST(&RCV 29 10))
  97.              MONMSG     MCH3601
  98.              CHGVAR     VAR(&JRNLIB) VALUE(%SST(&RCV 39 10))
  99.              MONMSG     MCH3601
  100.              CHGVAR     VAR(&WORK) VALUE(%SST(&RCV 49 4))
  101.              CHGVAR     VAR(&THRESHOLD) VALUE(%BIN(&WORK))
  102.              MONMSG     MCH3601
  103.              CHGVAR     VAR(&WORK) VALUE(%SST(&RCV 53 4))
  104.              CHGVAR     VAR(&SIZE) VALUE(%BIN(&WORK))
  105.              MONMSG     MCH3601
  106.              CHGVAR     VAR(&WORK) VALUE(%SST(&RCV 57 4))
  107.              CHGVAR     VAR(&ASP) VALUE(%BIN(&WORK))
  108.              MONMSG     MCH3601
  109.              CHGVAR     VAR(&WORK) VALUE(%SST(&RCV 61 4))
  110.              CHGVAR     VAR(&NBRENT) VALUE(%BIN(&WORK))
  111.              MONMSG     MCH3601
  112.              CHGVAR     VAR(&WORK) VALUE(%SST(&RCV 65 4))
  113.              CHGVAR     VAR(&MAXENTLEN) VALUE(%BIN(&WORK))
  114.              MONMSG     MCH3601
  115.              CHGVAR     VAR(&WORK) VALUE(%SST(&RCV 69 4))
  116.              CHGVAR     VAR(&MAXNULIND) VALUE(%BIN(&WORK))
  117.              MONMSG     MCH3601
  118.              CHGVAR     VAR(&WORK) VALUE(%SST(&RCV 73 4))
  119.              CHGVAR     VAR(&FSTSEQNBR) VALUE(%BIN(&WORK))
  120.              CHGVAR     VAR(&MINDTAARA) VALUE(%SST(&RCV 77 1))
  121.              CHGVAR     VAR(&MINDTAFLE) VALUE(%SST(&RCV 78 1))
  122.              CHGVAR     VAR(&WORK) VALUE(%SST(&RCV 81 4))
  123.              CHGVAR     VAR(&LSTSEQNBR) VALUE(%BIN(&WORK))
  124.              CHGVAR     VAR(&STATUS) VALUE(%SST(&RCV 89 1))
  125.              MONMSG     MCH3601
  126.              CHGVAR     VAR(&RCVMAXOPT) VALUE(%SST(&RCV 89 1))
  127.              MONMSG     MCH3601
  128.              CHGVAR     VAR(&ACTDATTIM) VALUE(%SST(&RCV 96 13))
  129.              MONMSG     MCH3601
  130.              CHGVAR     VAR(&DACTDATTIM) VALUE(%SST(&RCV 109 13))
  131.              MONMSG     MCH3601
  132.              CHGVAR     VAR(&SAVDATTIM) VALUE(%SST(&RCV 122 13))
  133.              MONMSG     MCH3601
  134.              CHGVAR     VAR(&NBRENT2) VALUE(%SST(&RCV 373 20))
  135.              CHGVAR     VAR(&NBRENTP) VALUE(&NBRENT2)
  136.              MONMSG     MCH3601
  137.              CHGVAR     VAR(&MAXENTLEN2) VALUE(%SST(&RCV 393 20))
  138.              CHGVAR     VAR(&MAXENTLENP) VALUE(&MAXENTLEN2)
  139.              MONMSG     MCH3601
  140.              CHGVAR     VAR(&FSTSEQNBRL) VALUE(%SST(&RCV 413 20))
  141.              CHGVAR     VAR(&FSTSEQNBRP) VALUE(&FSTSEQNBRL)
  142.              MONMSG     MCH3601
  143.              CHGVAR     VAR(&LSTSEQNBRL) VALUE(%SST(&RCV 433 20))
  144.              CHGVAR     VAR(&LSTSEQNBRP) VALUE(&LSTSEQNBRL)
  145.              MONMSG     MCH3601
  146.              CHGVAR     VAR(&TEXT) VALUE(%SST(&RCV 135 50))
  147.              MONMSG     MCH3601
  148.  
  149.              Return
  150.  
  151. /*  ===============================================================  */
  152. /*  = Error routine                                               =  */
  153. /*  ===============================================================  */
  154.  
  155. Error:
  156.  
  157.   RcvMsg     MsgType( *Excp )                                         +
  158.              MsgDta( &MsgDta )                                        +
  159.              MsgID( &MsgID )                                          +
  160.              MsgF( &MsgF )                                            +
  161.              MsgFLib( &MsgFLib )
  162.   MonMsg     ( CPF0000 MCH0000 )
  163.  
  164. SndMsg:
  165.  
  166.   SndPgmMsg  MsgID( &MsgID )                                          +
  167.              MsgF( &MsgFLib/&MsgF )                                   +
  168.              MsgDta( &MsgDta )                                        +
  169.              MsgType( *Escape )
  170.   MonMsg     ( CPF0000 MCH0000 )
  171.  
  172. /*  ===============================================================  */
  173. /*  = End of program                                              =  */
  174. /*  ===============================================================  */
  175.  
  176. ENDPGM
  177.  
  178.  
  179.  
  180. <b>
  181. File   : QCMDSRC
  182. Member : RTVJRNRCVA
  183. Type   : CMD
  184. Usage  : CRTCMD CMD(your-lib/RTVJRNRCVA) PGM(your-lib/RTVJRNRCVA) ALLOW(*IPGM *BPGM) 
  185. </b>
  186. /*  ===============================================================  */
  187. /*  = Command....... RtvJrnrcvA                                   =  */
  188. /*  = CPP........... RtvJrnRcvA CLLE                              =  */
  189. /*  = Description... Retrieve journal receiver attributes         =  */
  190. /*  =                                                             =  */
  191. /*  = CrtCmd      Cmd( RtvJrnrcvA )                               =  */
  192. /*  =             Pgm( RtvJrnrcvA )                               =  */
  193. /*  =             SrcFile( YourSourceFile )                       =  */
  194. /*  =             Allow(*Ipgm *Bpgm)                              =  */
  195. /*  ===============================================================  */
  196. /*  = Date  : 2008/03/14                                          =  */
  197. /*  = Author: Vengoal Chang                                       =  */
  198. /*  ===============================================================  */
  199. /*  = Parameter     Description                                   =  */
  200. /*  =   JRNRCV      The qualified name of the journal receiver to =  */
  201. /*  =               be retrieved.                                 =  */
  202. /*  =   RTNLIB      The library containing the journal receiver.  =  */
  203. /*  =   STATUS      The status of the journal receiver. One of the=  */
  204. /*  =               following values will be returned:            =  */
  205. /*  =               *ATTACHED   Currently attached                =  */
  206. /*  =               *ONLINE     On line, detached, but not saved  =  */
  207. /*  =               *SAVED      On line, detached, and saved      =  */
  208. /*  =               *FREED      On line, detached, saved and stg  =  */
  209. /*  =                           freed.                            =  */
  210. /*  =               *PARTIAL    See API detail                    =  */
  211. /*  =                           QjoRetrieveJournalInformation     =  */
  212. /*  =               *EMPTY      Never attached                    =  */
  213. /*  =   ASP         The Auxiliary Storage pool containing the     =  */
  214. /*  =               journal.                                      =  */
  215. /*  =   THRESHOLD   The value of the THRESHOLD parameter specified=  */
  216. /*  =               on CRTJRNRCV                                  =  */
  217. /*  =   SIZE        The size of the journal receiver.specified    =  */
  218. /*  =               The value is in KB.                           =  */
  219. /*  =   NBRENT      The number of entries in the journal receiver.=  */
  220. /*  =   MAXNULLIND  The maximum number of null value indicators   =  */
  221. /*  =               among all journal entries in this journal     =  */
  222. /*  =               receiver.                                     =  */
  223. /*  =   MAXENTLEN   The maximum length of the entry specific data =  */
  224. /*  =               for any journal entry, If the value exceeds   =  */
  225. /*  =               99999, zero willbe returned.(use MAXENTLEN2). =  */
  226. /*  =   MAXENTLEN2  The maximum length of the entry specific data =  */
  227. /*  =               for any journal entry                         =  */
  228. /*  =   RCVMAXOPT   Indicates the journal receiver sequence number=  */
  229. /*  =               and size options.                             =  */
  230. /*  =               Blank means the journal receiver has not yet  =  */
  231. /*  =               been attached. A description of the codes can =  */
  232. /*  =               be found in QjoRtvJrnReceiverInformation API. =  */
  233. /*  =   FSTSEQNBR   The first journal sequence number in the      =  */
  234. /*  =               receiver.                                     =  */
  235. /*  =   LSTSEQNBR   The last journal sequence number in the       =  */
  236. /*  =               receiver.                                     =  */
  237. /*  =   ATCDATTIM   The date the journal receiver was attached in =  */
  238. /*  =               the format CYYMMDDHHMMSS                      =  */
  239. /*  =   DATCDATTIM  The date the journal receiver was detached in =  */
  240. /*  =               the format CYYMMDDHHMMSS                      =  */
  241. /*  =   SAVDATTIM   The date the journal receiver was saved    in =  */
  242. /*  =               the format CYYMMDDHHMMSS                      =  */
  243. /*  =   JRN         The journal the receiver is or was attached to=  */
  244. /*  =               If never attached, the value will be blank.   =  */
  245. /*  =   JRNLIB      The library of the journal the receiver is or =  */
  246. /*  =               was attached to. If never attached, the value =  */
  247. /*  =               will be blank.                                =  */
  248. /*  =   TEXT        The text description of the journal receiver. =  */
  249. /*  ===============================================================  */
  250.              CMD        PROMPT('Retrieve Journal Receiver Atr')
  251.  
  252.              PARM       KWD(JRNRCV) TYPE(QUAL) MIN(1) +
  253.                           PROMPT('Journal receiver')
  254.  
  255.              PARM       KWD(RTNLIB) TYPE(*CHAR) LEN(10) RTNVAL(*YES) +
  256.                           PROMPT('CL var for RTNLIB       (10)')
  257.              PARM       KWD(STATUS) TYPE(*CHAR) LEN(1) RTNVAL(*YES) +
  258.                           PROMPT('CL var for STATUS       ( 1)')
  259.              PARM       KWD(ASP) TYPE(*DEC) LEN(3 0) RTNVAL(*YES) +
  260.                           PROMPT('CL var for ASP         (3 0)')
  261.              PARM       KWD(THRESHOLD) TYPE(*DEC) LEN(7 0) +
  262.                           RTNVAL(*YES) PROMPT('CL var for +
  263.                           THRESHOLD   (7 0)')
  264.              PARM       KWD(SIZE) TYPE(*DEC) LEN(7 0) RTNVAL(*YES) +
  265.                           PROMPT('CL var for SIZE        (7 0)')
  266.              PARM       KWD(NBRENT) TYPE(*DEC) LEN(15 0) +
  267.                           RTNVAL(*YES) PROMPT('CL var for +
  268.                           NBRENT     (15 0)')
  269.              PARM       KWD(MAXNULLIND) TYPE(*DEC) LEN(15 0) +
  270.                           RTNVAL(*YES) PROMPT('CL var for +
  271.                           MAXNULLIND (15 0)')
  272.              PARM       KWD(MAXENTLEN) TYPE(*DEC) LEN( 7 0) +
  273.                           RTNVAL(*YES) PROMPT('CL var for +
  274.                           MAXENTLEN  (15 0)')
  275.              PARM       KWD(MAXENTLEN2) TYPE(*DEC) LEN(15 0) +
  276.                           RTNVAL(*YES) PROMPT('CL var for +
  277.                           MAXENTLEN2 (15 0)')
  278.              PARM       KWD(RCVMAXOPT ) TYPE(*CHAR) LEN(1) +
  279.                           RTNVAL(*YES) PROMPT('CL var for +
  280.                           RCVMAXOPT     (1)')
  281.              PARM       KWD(FSTSEQNBR) TYPE(*DEC) LEN(15 0) +
  282.                           RTNVAL(*YES) PROMPT('CL var for +
  283.                           FSTSEQNBR  (15 0)')
  284.              PARM       KWD(LSTSEQNBR) TYPE(*DEC) LEN(15 0) +
  285.                           RTNVAL(*YES) PROMPT('CL var for +
  286.                           LSTSEQNBR  (15 0)')
  287.              PARM       KWD(ACTDATTIM) TYPE(*CHAR) LEN(13) +
  288.                           RTNVAL(*YES) PROMPT('CL var for +
  289.                           ACTDATTIM    (13)')
  290.              PARM       KWD(DACTDATTIM) TYPE(*CHAR) LEN(13) +
  291.                           RTNVAL(*YES) PROMPT('CL var for +
  292.                           DACTDATTIM   (13)')
  293.              PARM       KWD(SAVDATTIM) TYPE(*CHAR) LEN(13) +
  294.                           RTNVAL(*YES) PROMPT('CL var for +
  295.                           SAVDATTIM    (13)')
  296.              PARM       KWD(JRN) TYPE(*CHAR) LEN(10) +
  297.                           RTNVAL(*YES) PROMPT('CL var for +
  298.                           JRN          (10)')
  299.              PARM       KWD(JRNLIB) TYPE(*CHAR) LEN(10) +
  300.                           RTNVAL(*YES) PROMPT('CL var for +
  301.                           JRNLIB       (10)')
  302.              PARM       KWD(TEXT) TYPE(*CHAR) LEN(50) +
  303.                           RTNVAL(*YES) PROMPT('CL var for +
  304.                           TEXT         (50)')
  305.  
  306.  
  307.  QUAL:       QUAL       TYPE(*NAME) LEN(10) SPCVAL((*ALL)) EXPR(*YES)
  308.              QUAL       TYPE(*NAME) LEN(10) DFT(*LIBL) +
  309.                           SPCVAL((*LIBL) (*CURLIB)) EXPR(*YES) +
  310.                           PROMPT('Library')
  311.  
  312.  
© 2004-2019 by midrange.com generated in 0.008s valid xhtml & css